La nueva función BUSCARX de Excel ha venido para quedarse y, sobre todo, para facilitarnos mucho la vida. Esta función puede sustituir otras funciones de búsqueda como buscarv, buscarh, índice y coincidir. Te enseñamos todas las posibilidades en este tutorial.

¿En qué versión de Excel está disponible la función BUSCARX?

La función BUSCARX está disponible para Excel 365, si tienes una versión antigua de Excel, como Excel 2010 o Excel 2016 no tendrás esta función.

Puedes comprobar si tu Excel tiene la función escribiendo en cualquier celda =buscar

En las funciones disponibles debe aparecer BUSCARX.

También puedes comprobar la versión de tu Excel. Clica en Archivo, en el menú izquierdo selecciona la opción Cuenta y comprueba en el apartado Acerca de Excel la versión que estás utilizando.

La función está disponible desde la versión 1910 de Excel.

Cómo usar la función BUSCARX en Excel

Para ver el uso de la función BUSCARX en Excel utilizaremos un ejemplo en el que se muestra un listado de comerciales, la zona en la que trabajan y las ventas anuales. En otra hoja llamada bonificación tenemos otra tabla con el ID de cada comercial, su nombre y el porcentaje bonificación sobre las ventas que han conseguido. Puedes descargarte la plantilla al final de este artículo.

Utilizando la función BUSCARX queremos calcular el importe de la bonificación sobre las ventas que han conseguido. Necesitamos buscar el porcentaje de bonificación para cada uno de los comerciales.

En la primera celda de la columna correspondiente escribe =BUSCARX donde:

  • Valor_buscado será el nombre del comercial que también aparece en la lista de bonificaciones.
  • Matriz_buscada corresponde a toda la columna de nombres de comerciales en la tabla de la hoja bonificación (establecemos una referencia absoluta presionando F4)
  • Matriz_devuelta son todos los datos de la columna porcentajes de bonificación, también fijaremos este valor pulsando F4.

Estos 3 son los argumentos obligatorios de la nueva función BUSCARX. Los otros 3 argumentos son opcionales, los veremos con otros ejemplos.

La función quedaría así:

=BUSCARX(A5;Bonificaciones!$B$6:$B$25;Bonificaciones!$C$6:$C$25)

Nos devuelve el valor de la bonificación, para calcular el importe solo debes multiplicar ese valor por el importe de ventas, quedando de la siguiente forma:

=BUSCARX(A5;Bonificaciones!$B$6:$B$25;Bonificaciones!$C$6:$C$25)*C5

Como evitar error #N/D

Observa que al arrastrar la función al resto de celdas de la columna, en algunos casos arroja el error #N/D.

BUSCARX en Excel

Este error suele aparecer cuando utilizamos las funciones BUSCARV, BUSCARH, BUSCAR, COINCIDIR y también en la nueva función BUSCARX y se produce cuando en una fórmula no se encuentra el valor al que se hace referencia. Como en este caso, algunos de los nombres de los comerciales no existen en los datos de bonificaciones.

Este error es muy sencillo de solventar cuando usas la función BUSCARX. Solo tienes que aplicar un valor para el cuarto argumento de la función. Se trata del argumento Si_no_se_encuentra para ese valor aplicaremos el valor 0. Escribe ; tras el último argumento, antes del paréntesis de cierre y a continuación un 0.

La función ahora quedaría así:

=BUSCARX(A5;Bonificaciones!$B$6:$B$25;Bonificaciones!$C$6:$C$25;0)*C5

Buscar en horizontal con BUSCARX en Excel

Antes de la función BUSCARX, cuando necesitábamos realizar una búsqueda en una tabla estructurada de forma horizontal debíamos utilizar la función BUSCARH. La nueva función BUSCARX también puede realizar búsquedas horizontales sin problema.

El proceso es exactamente igual. Para verlo calcularemos de nuevo la bonificación, pero en este caso usaremos la tabla horizontal de la hoja Bonificaciones.

La función realizando la búsqueda horizontal quedaría así:

=BUSCARX(A5;Bonificaciones!$G$8:$Z$8;Bonificaciones!$G$9:$Z$9;0)*C5

Caracteres comodín en BUSCARX

En algunos casos necesitamos realizar búsquedas con coincidencia parcial. En esos casos podemos usar tanto asteriscos como signos de interrogación y combinarlos con el valor buscado. Vamos a ver cómo aplicarlo en la función BUSCARX.

Supongamos que no conocemos el nombre de todos los comerciales, pero sí su apellido. Queremos que al introducir el apellido en una celda obtener la bonificación usando la función BUSCARX donde:

  • Valor_buscado será el apellido que se muestra en la celda G7. Para indicar que puede haber texto delante escribiremos justo delante de la referencia a la celda “*” y para unirlo a la referencia de la celda usa el símbolo &. Quedando el primer argumento de la siguiente forma: =BUSCARX(«*»&G7;
  • Matriz_buscada corresponde a toda la columna de nombres de comerciales.
  • Matriz_devuelta son todos los datos de la columna bonificación que has calculado anteriormente.

Como la búsqueda que estás realizando no es una búsqueda exacta debes indicarlo en el quinto argumento de la función BUSCARX para que funcione correctamente. El cuarto argumento lo dejaremos vacío.

BUSCARX en Excel

En el quinto argumento modo_de_coincidencia existe la opción coincidencia de caracteres comodín, que debes seleccionar en estos casos. Su valor es 2.

Quedando la función de la siguiente forma:

=BUSCARX(«*»&G7;A5:A19;D5:D19;;2)

Buscar por fila y columna con BUSCARX

Utilizando la función BUSCARX también puedes realizar búsquedas bidireccionales. Para buscar un valor tanto en las filas como en las columnas, usábamos las combinaciones de funciones BUSCARV Y COINCIDIR o bien INDICE y COINCIDIR. Con la función BUSCARX ya no necesitas utilizar dos funciones separadas. Puedes utilizar la BUSCARX anidada.

En la plantilla tenemos hemos insertado una lista desplegable en la que se elige el comercial y otra lista en la que se selecciona el campo a mostrar (Zona, ventas anual o bonificación) queremos armar una función BUSCARX que muestre el dato correspondiente al comercial y campo seleccionado.

En este caso en la función BUSCARX:

  • Valor_buscado será el la celda donde hemos insertado la lista desplegable con los nombres de comercial H15.
  • Matriz_buscada corresponde a toda la columna de nombres de comerciales A5:A19.
  • Matriz_devuelta dependerá del campo seleccionado, por lo que escribiremos de nuevo otra función BUSCARX donde:
    • Valor_buscado de la segunda buscarx será el campo seleccionado que se muestra en la celda G16.
    • Matriz_buscada de la segunda buscarx serán los encabezados donde se muestran los tres campos B4:D4.
    • Matriz_devuelta de la segunda buscarx serán todos los datos B5:B19.

Quedando la función de la siguiente forma:

=BUSCARX(H15;A5:A19;BUSCARX(G16;B4:D4;B5:D19))

BUSCARX en Excel

Buscar valores aproximados con BUSCARX

Cuando necesitas buscar dentro de una tabla de datos el valor más aproximado, también puedes hacerlo con la función BUSCARX. Lo puedes usar para calcular descuentos, bonificaciones etc. En este caso usaremos el argumento opcional modo de coincidencia.

Lo veremos con el siguiente ejemplo, añadimos una columna más a los datos en la que queremos mostrar el porcentaje de bonificación que corresponde según la siguiente tabla.

Para poder calcular el porcentaje se debe buscar el valor aproximado según la tabla. Usaremos la función BUSCARX donde:

  • Valor_buscado será el importe de ventas anual.
  • Matriz_buscada corresponde a todos los importes de ventas de la tabla en la que muestra el porcentaje de bonificación por rangos.
  • Matriz_devuelta serán los porcentajes de bonificación según el rango.

En este caso tampoco necesitas realizar una búsqueda exacta, por lo que de nuevo debes usar el 5º argumento modo_de_coincidencia.

  • Modo_de_coincidencia debes seleccionar la opción coincidencia exacta o el siguiente elemento menor, al que corresponde el valor -1.

La función quedaría de la siguiente forma:

=BUSCARX(C5;Bonificaciones!$F$16:$F$21;Bonificaciones!$G$16:$G$21;;-1)

Plantilla de los ejercicios

Puedes descargar la plantilla para practicar aquí:

Esta plantilla es un recurso creado por Saber Programas y su uso está sujeto a derechos de autor y propiedad intelectual.

Resumen de la función BUSCARX

Si has seguido el tutorial completo habrás comprobado que la nueva función BUSCARX es muy potente y puede sustituir varias funciones. Esto hace que el manejo de Excel sea más sencillo, ya que solo tendrás que aprender bien el uso de esta función para sustituir otras funciones.

¿Habías utilizado antes esta función? Danos tu opinión sobre ella.